Vlookup函數的教程網上已非常多了，而貼近工作用的Vlookup函數應用示例卻很少。今天小編給大家帶來一期Vlookup函數示例大全，希望能給大家的工作帶來幫助。

【例1】查找個人信息

=VLOOKUP($B18,$C$7:$H$15,COLUMN(B1),0)

注：Colum(b1)的結果是2，當公式向右複制時可以生成3，4，5，..

【例2】合并兩個表格

F2單元格公式

=VLOOKUP(B2,$B$14:$F$22,MATCH(F$1,$B$13:$F$13,0))

公式說明：用Match函數查找表1的标題在表2中的位置

【例3】讓兩個表格同類商品排序完全一樣

F2單元格公式

=IFERROR(VLOOKUP($B2,$B$12:$D$16,COLUMN(A1),),"")

公式說明：IFERROR函數用來屏蔽錯誤值

【例4】制作工資條

=VLOOKUP($G96,$A$96:$E$104,COLUMN(B1),)

公式說明：根據序号從工資表中查找對應的信息

【例5】計算個人所得稅

=(G28-3500)*VLOOKUP(G28-3500,C28:E34,2)-VLOOKUP(G28-3500,C28:E34,3)

公式說明：當Vlookup最後一個參數為1或省略時，查找為近似匹配。即查找比指定值小且最接近的值。

【例6】模糊查找産品名稱（包含查找）

=VLOOKUP("*"&F41&"*",$B$41:$D$47,3,0)

注：*是通配符，代表任意多個字符

【例7】帶特殊符合的字符查找

=VLOOKUP(SUBSTITUTE(F52,"~","~~"),B$52:C$56,2,0)

注：由于~ * ？在公式中有通配符用法，遇到被查找的字符串中含有這3個字符就用Substitute替換為~~、~*和~？

【例8】逆向查找

=VLOOKUP(G61,IF({1,0},C61:C69,B61:B69),2,)

公式說明: 本公式隻做了解，遇到逆向查找，建議使用Index Match函數。

=INDEX(B60:B69,MATCH(G61,C60:C69,0))

【例9】16年與17年單價核對，表格核對（帶通配符），結果顯示多N 或 少N

=TEXT(VLOOKUP(SUBSTITUTE(B73,"*","~*"),$F$73:$G$92,2,)-C73,"少0.00;多0.00;")

公式說明:Text可以設置數字顯示的格式

【例10】Vlookup多條件查找

A112 =B112&C112

H112 =VLOOKUP(F112&G112,A112:D120,4,0)

公式說明：Vlookup也可以使用IF({1,0}的數組形式實現多條件查找，但運行效率太慢，所以建議使用輔助列連接再查找的方法。

【例11】庫存單價的監控。銷售單價>庫存單價時填充紅色背景

設置方法：選取區域 - 條件格式 - 新建規則 - 使用公式确定... - 在下面框中輸入公式：

=H2>VLOOKUP(F2,A:C,3,0)

最後點“格式”按鈕設置填充色為紅色

【例12】銀行存款最近30天到期提醒。表中要有某天彙總金額，也要有明細金額。

設置方法：

步驟1添加輔助列，根據到期日生成 到期日 序列（目的是對同一個日期編序号，方便Vlookup一對多查找）

=D2&"-"&COUNTIF(D$2:D2,D2)

步驟2設置到期日公式，H2單元格輸入=Today() ,H3=H2 1,然後H3公式向下複制

步驟3設置求和公式，用來統計每個到期時需要還款的總金額

=SUMIF(D:D,H2,C:C)

步驟4用Vlookup查找各行明細數據

J2單元格公式

=IFERROR(VLOOKUP($H2&"-"&J$1,$A:$D,2,0)&":"&VLOOKUP($H2&"-"&J$1,$A:$D,3,0),"")

公式說明： 這裡把H列日期&第1行的數字作為查找内容，在A列中進行查找，然後返回B列 & C列的數據，

小編說：如果你覺得有用，一定要幫助小編分享給更多需要的朋友們。